Add backend selection option

Author: K-ballo

CMakeLists.txt

@@ -137,27 +137,14 @@ if(MSVC)
     )
 endif()
 
-# -- Backend selection -----------------------------------------------------
+# -- Backend helpers -------------------------------------------------------
 
-# eggs_stacktrace_want_backend(<name> <out-var>)
+# eggs_stacktrace_add_backend(<name>)
 #
-# Sets <out-var> ON if <name> should be attempted: always, unless
-# EGGS_STACKTRACE_BACKENDS is non-empty and doesn't list it.
-macro(eggs_stacktrace_want_backend name out_var)
-    if(
-        EGGS_STACKTRACE_BACKENDS
-        AND NOT "${name}" IN_LIST EGGS_STACKTRACE_BACKENDS
-    )
-        set(${out_var} OFF)
-    else()
-        set(${out_var} ON)
-    endif()
-endmacro()
-
-# -- Backend macro -------------------------------------------------------------
-
-macro(eggs_stacktrace_add_backend name)
+# Defines the _eggs_stacktrace_<name> target.
+function(eggs_stacktrace_add_backend name)
     set(_export "${EGGS_STACKTRACE_BACKEND_EXPORT_${name}}")
+    string(TOUPPER "${name}" _upper)
     add_library(
         _eggs_stacktrace_${name}
         STATIC
@@ -171,6 +158,12 @@ macro(eggs_stacktrace_add_backend name)
             $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
     )
     target_compile_features(_eggs_stacktrace_${name} PUBLIC cxx_std_11)
+    if(EGGS_STACKTRACE_${_upper}_DEFINITIONS)
+        target_compile_definitions(
+            _eggs_stacktrace_${name}
+            PRIVATE ${EGGS_STACKTRACE_${_upper}_DEFINITIONS}
+        )
+    endif()
     set_target_properties(
         _eggs_stacktrace_${name}
         PROPERTIES
@@ -187,76 +180,53 @@ macro(eggs_stacktrace_add_backend name)
                     "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIG>"
         )
     endif()
-    if(NOT "${ARGN}" STREQUAL "")
-        target_link_libraries(_eggs_stacktrace_${name} PUBLIC ${ARGN})
-    endif()
-    add_library(Eggs::Stacktrace::${_export} ALIAS _eggs_stacktrace_${name})
-    unset(_export)
-endmacro()
-
-# -- Backend targets -----------------------------------------------------------
-
-eggs_stacktrace_add_backend(null)
-
-eggs_stacktrace_want_backend(execinfo _want_execinfo)
-if(_want_execinfo)
-    include(CheckExecinfoBackend)
-    eggs_stacktrace_check_execinfo_backend(EGGS_STACKTRACE_HAVE_EXECINFO)
-    if(EGGS_STACKTRACE_HAVE_EXECINFO)
-        eggs_stacktrace_add_backend(execinfo _eggs_stacktrace_execinfo_support)
-    elseif("execinfo" IN_LIST EGGS_STACKTRACE_BACKENDS)
-        message(
-            FATAL_ERROR
-            "Eggs.Stacktrace: backend 'execinfo' was requested in "
-            "EGGS_STACKTRACE_BACKENDS but is not available on this platform."
+    if(TARGET _eggs_stacktrace_${name}_support)
+        target_link_libraries(
+            _eggs_stacktrace_${name}
+            PUBLIC _eggs_stacktrace_${name}_support
         )
     endif()
-else()
-    set(EGGS_STACKTRACE_HAVE_EXECINFO OFF)
-endif()
+    add_library(Eggs::Stacktrace::${_export} ALIAS _eggs_stacktrace_${name})
+endfunction()
 
-eggs_stacktrace_want_backend(libbacktrace _want_libbacktrace)
-if(_want_libbacktrace)
-    include(CheckLibbacktraceBackend)
-    eggs_stacktrace_check_libbacktrace_backend(
-        EGGS_STACKTRACE_HAVE_LIBBACKTRACE
+# eggs_stacktrace_add_checked_backend(<name>)
+#
+# Adds backend <name> if it is wanted and its dependencies check out.
+macro(eggs_stacktrace_add_checked_backend name)
+    string(TOUPPER "${name}" _upper)
+    if(
+        NOT EGGS_STACKTRACE_BACKENDS
+        OR "${name}" IN_LIST EGGS_STACKTRACE_BACKENDS
     )
-    if(EGGS_STACKTRACE_HAVE_LIBBACKTRACE)
-        eggs_stacktrace_add_backend(
-            libbacktrace
-            _eggs_stacktrace_libbacktrace_support
-        )
-        target_compile_definitions(
-            _eggs_stacktrace_libbacktrace
-            PRIVATE
-                EGGS_STACKTRACE_BACKTRACE_INCLUDE_FILE="${EGGS_STACKTRACE_LIBBACKTRACE_HEADER}"
-        )
-    elseif("libbacktrace" IN_LIST EGGS_STACKTRACE_BACKENDS)
-        message(
-            FATAL_ERROR
-            "Eggs.Stacktrace: backend 'libbacktrace' was requested in "
-            "EGGS_STACKTRACE_BACKENDS but is not available on this platform."
+        include(Check${EGGS_STACKTRACE_BACKEND_EXPORT_${name}}Backend)
+        cmake_language(
+            CALL eggs_stacktrace_check_${name}_backend
+            EGGS_STACKTRACE_HAVE_${_upper}
         )
+        if(EGGS_STACKTRACE_HAVE_${_upper})
+            eggs_stacktrace_add_backend(${name})
+            list(
+                APPEND EGGS_STACKTRACE_CHECKED_BACKENDS
+                ${EGGS_STACKTRACE_BACKEND_EXPORT_${name}}
+            )
+        elseif("${name}" IN_LIST EGGS_STACKTRACE_BACKENDS)
+            message(
+                FATAL_ERROR
+                "Eggs.Stacktrace: backend '${name}' was requested in "
+                "EGGS_STACKTRACE_BACKENDS but is not available on this platform."
+            )
+        endif()
     endif()
-else()
-    set(EGGS_STACKTRACE_HAVE_LIBBACKTRACE OFF)
-endif()
+    unset(_upper)
+endmacro()
 
-eggs_stacktrace_want_backend(win32 _want_win32)
-if(_want_win32)
-    if(WIN32)
-        set(EGGS_STACKTRACE_HAVE_WIN32 ON)
-        eggs_stacktrace_add_backend(win32 DbgHelp)
-    elseif("win32" IN_LIST EGGS_STACKTRACE_BACKENDS)
-        message(
-            FATAL_ERROR
-            "Eggs.Stacktrace: backend 'win32' was requested in "
-            "EGGS_STACKTRACE_BACKENDS but is not available on this platform."
-        )
-    endif()
-else()
-    set(EGGS_STACKTRACE_HAVE_WIN32 OFF)
-endif()
+# -- Backend targets -----------------------------------------------------------
+
+set(EGGS_STACKTRACE_CHECKED_BACKENDS)
+eggs_stacktrace_add_backend(null)
+eggs_stacktrace_add_checked_backend(execinfo)
+eggs_stacktrace_add_checked_backend(libbacktrace)
+eggs_stacktrace_add_checked_backend(win32)
 
 # An empty EGGS_STACKTRACE_BACKENDS means auto-detect.
 if(NOT EGGS_STACKTRACE_BACKENDS)
@@ -284,15 +254,14 @@ if(EGGS_STACKTRACE_DEFAULT_BACKEND)
         )
     endif()
 else()
-    if(TARGET _eggs_stacktrace_libbacktrace)
-        set(EGGS_STACKTRACE_DEFAULT_BACKEND libbacktrace)
-    elseif(TARGET _eggs_stacktrace_execinfo)
-        set(EGGS_STACKTRACE_DEFAULT_BACKEND execinfo)
-    elseif(TARGET _eggs_stacktrace_win32)
-        set(EGGS_STACKTRACE_DEFAULT_BACKEND win32)
-    else()
-        set(EGGS_STACKTRACE_DEFAULT_BACKEND null)
-    endif()
+    set(EGGS_STACKTRACE_DEFAULT_BACKEND null)
+    foreach(_backend IN ITEMS libbacktrace execinfo win32)
+        if(TARGET _eggs_stacktrace_${_backend})
+            set(EGGS_STACKTRACE_DEFAULT_BACKEND ${_backend})
+            break()
+        endif()
+    endforeach()
+    unset(_backend)
 endif()
 
 add_library(
@@ -377,6 +346,7 @@ if(ENABLE_INSTALL)
         FILES
             cmake/CheckExecinfoBackend.cmake
             cmake/CheckLibbacktraceBackend.cmake
+            cmake/CheckWin32Backend.cmake
             cmake/FindLibbacktrace.cmake
         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/eggs.stacktrace
     )

cmake/CheckLibbacktraceBackend.cmake

@@ -15,17 +15,18 @@ list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
 #
 # Checks whether libbacktrace is present and links successfully.
 # Sets <out-var> as an internal cache boolean. On success, also defines the
-# INTERFACE library _eggs_stacktrace_libbacktrace_support. Additionaly,
-# sets EGGS_STACKTRACE_LIBBACKTRACE_HEADER to the resolved header path..
+# INTERFACE library _eggs_stacktrace_libbacktrace_support. Additionally,
+# sets EGGS_STACKTRACE_LIBBACKTRACE_DEFINITIONS to the private compile
+# definitions the backend needs, including the resolved header path.
 function(eggs_stacktrace_check_libbacktrace_backend out_var)
     find_package(Libbacktrace QUIET)
     set(${out_var} ${Libbacktrace_FOUND} CACHE INTERNAL "")
     if(NOT Libbacktrace_FOUND)
         return()
     endif()
 
-    set(EGGS_STACKTRACE_LIBBACKTRACE_HEADER
-        "${Libbacktrace_HEADER}"
+    set(EGGS_STACKTRACE_LIBBACKTRACE_DEFINITIONS
+        "EGGS_STACKTRACE_BACKTRACE_INCLUDE_FILE=\"${Libbacktrace_HEADER}\""
         PARENT_SCOPE
     )
     if(NOT TARGET _eggs_stacktrace_libbacktrace_support)

cmake/CheckWin32Backend.cmake

@@ -0,0 +1,47 @@
+# Eggs.Stacktrace
+#
+# Copyright (c) 2026 Agustin Berge
+#
+# Distributed under the Boost Software License, Version 1.0. (See accompanying
+# file LICENSE.txt or copy at http://www.boost.org/LICENSE_1_0.txt)
+
+include_guard()
+
+include(CheckCXXSourceCompiles)
+
+# eggs_stacktrace_check_win32_backend(<out-var>)
+#
+# Checks whether the win32 backend's dependencies (CaptureStackBackTrace()
+# and the DbgHelp symbol APIs) are all present and link successfully.
+# Sets <out-var> as an internal cache boolean. On success, also defines the
+# INTERFACE library _eggs_stacktrace_win32_support.
+function(eggs_stacktrace_check_win32_backend out_var)
+    set(CMAKE_REQUIRED_LIBRARIES DbgHelp)
+    check_cxx_source_compiles(
+        "
+        #include <windows.h>
+        #include <dbghelp.h>
+        int main()
+        {
+            void* buf[1];
+            USHORT const n = ::CaptureStackBackTrace(0, 1, buf, nullptr);
+            HANDLE const process = ::GetCurrentProcess();
+            ::SymInitialize(process, nullptr, TRUE);
+            ::SymRefreshModuleList(process);
+            ::SymGetLineFromAddr64(process, 0, nullptr, nullptr);
+            ::SymFromAddr(process, 0, nullptr, nullptr);
+            ::SymCleanup(process);
+            return n;
+        }
+        "
+        ${out_var}
+    )
+    if(NOT ${out_var})
+        return()
+    endif()
+
+    if(NOT TARGET _eggs_stacktrace_win32_support)
+        add_library(_eggs_stacktrace_win32_support INTERFACE)
+        target_link_libraries(_eggs_stacktrace_win32_support INTERFACE DbgHelp)
+    endif()
+endfunction()

cmake/eggs.stacktrace-config.cmake.in

@@ -2,41 +2,28 @@
 
 include("${CMAKE_CURRENT_LIST_DIR}/eggs.stacktrace-targets.cmake")
 
-if(@EGGS_STACKTRACE_HAVE_EXECINFO@)
-    include("${CMAKE_CURRENT_LIST_DIR}/CheckExecinfoBackend.cmake")
-    eggs_stacktrace_check_execinfo_backend(EGGS_STACKTRACE_HAVE_EXECINFO)
-    if(EGGS_STACKTRACE_HAVE_EXECINFO)
-        include(
-            "${CMAKE_CURRENT_LIST_DIR}/eggs.stacktrace-execinfo-targets.cmake"
-        )
-    else()
-        message(
-            WARNING
-            "eggs.stacktrace: execinfo backend dependencies could not be resolved on this machine; the Execinfo backend will not be available"
-        )
-    endif()
-endif()
-
-if(@EGGS_STACKTRACE_HAVE_LIBBACKTRACE@)
-    include("${CMAKE_CURRENT_LIST_DIR}/CheckLibbacktraceBackend.cmake")
-    eggs_stacktrace_check_libbacktrace_backend(
-        EGGS_STACKTRACE_HAVE_LIBBACKTRACE
+foreach(_export IN ITEMS @EGGS_STACKTRACE_CHECKED_BACKENDS@)
+    string(TOLOWER "${_export}" _backend)
+    string(TOUPPER "${_export}" _upper)
+    include("${CMAKE_CURRENT_LIST_DIR}/Check${_export}Backend.cmake")
+    cmake_language(
+        CALL eggs_stacktrace_check_${_backend}_backend
+        EGGS_STACKTRACE_HAVE_${_upper}
     )
-    if(EGGS_STACKTRACE_HAVE_LIBBACKTRACE)
+    if(EGGS_STACKTRACE_HAVE_${_upper})
         include(
-            "${CMAKE_CURRENT_LIST_DIR}/eggs.stacktrace-libbacktrace-targets.cmake"
+            "${CMAKE_CURRENT_LIST_DIR}/eggs.stacktrace-${_backend}-targets.cmake"
         )
     else()
         message(
             WARNING
-            "eggs.stacktrace: libbacktrace could not be found on this machine; the Libbacktrace backend will not be available"
+            "eggs.stacktrace: ${_backend} backend dependencies could not be resolved on this machine; the ${_export} backend will not be available"
         )
     endif()
-endif()
-
-if(@EGGS_STACKTRACE_HAVE_WIN32@)
-    include("${CMAKE_CURRENT_LIST_DIR}/eggs.stacktrace-win32-targets.cmake")
-endif()
+endforeach()
+unset(_export)
+unset(_backend)
+unset(_upper)
 
 # Create the canonical Eggs::Stacktrace alias for the configured default backend.
 if(NOT TARGET Eggs::Stacktrace)